1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
/* Copyright (C) 2002 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#define SYS_futex 240
#define FUTEX_WAIT 0
#define FUTEX_WAKE 1
#ifndef UP
# define LOCK lock
#else
# define LOCK
#endif
#define CURR_EVENT 0
#define MUTEX 4
#define LEFT 8
#define INIT_COUNT 12
.text
.globl pthread_barrier_wait
.type pthread_barrier_wait,@function
.align 16
pthread_barrier_wait:
pushl %esi
pushl %ebx
movl 12(%esp), %ebx
xorl %esi, %esi
/* Get the mutex. */
orl $-1, %eax
LOCK
xaddl %eax, MUTEX(%ebx)
jne 1f
/* One less waiter. If this was the last one needed wake
everybody. */
2: decl LEFT(%ebx)
je 3f
/* There are more threads to come. */
movl CURR_EVENT(%ebx), %edx
/* Release the mutex. */
LOCK
incl MUTEX(%ebx)
jng 6f
/* Wait for the remaining threads. The call will return immediately
if the CURR_EVENT memory has meanwhile been changed. */
7: movl %esi, %ecx /* movl $FUTEX_WAIT, %ecx */
8: movl $SYS_futex, %eax
int $0x80
/* Don't return on spurious wakeups. The syscall does not change
any register except %eax so there is no need to reload any of
them. */
cmpl %edx, CURR_EVENT(%ebx)
je,pn 8b
/* Note: %esi is still zero. */
movl %esi, %eax /* != PTHREAD_BARRIER_SERIAL_THREAD */
popl %ebx
popl %esi
ret
/* The necessary number of threads arrived. */
3: movl INIT_COUNT(%ebx), %eax
movl %eax, LEFT(%ebx)
incl CURR_EVENT(%ebx)
/* Wake up all waiters. The count is a signed number in the kernel
so 0x7fffffff is the highest value. */
movl $0x7fffffff, %edx
movl $FUTEX_WAKE, %ecx
movl $SYS_futex, %eax
int $0x80
/* Release the mutex. */
LOCK
incl MUTEX(%ebx)
jng 4f
5: orl $-1, %eax /* == PTHREAD_BARRIER_SERIAL_THREAD */
popl %ebx
popl %esi
ret
1: leal MUTEX(%ebx), %ecx
call __lll_lock_wait
jmp 2b
4: leal MUTEX(%ebx), %eax
call __lll_unlock_wake
jmp 5b
6: leal MUTEX(%ebx), %eax
call __lll_unlock_wake
jmp 7b
.size pthread_barrier_wait,.-pthread_barrier_wait
|
