summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat
-rw-r--r--nptl/ChangeLog9
-rw-r--r--nptl/sysdeps/unix/sysv/linux/x86_64/libc-lowlevelmutex.S30
-rw-r--r--nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.S2
-rw-r--r--nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.h16
-rw-r--r--nptl/sysdeps/unix/sysv/linux/x86_64/lowlevelmutex.S164
5 files changed, 212 insertions, 9 deletions
diff --git a/nptl/ChangeLog b/nptl/ChangeLog
index 79fb9db285..a0b21e8575 100644
--- a/nptl/ChangeLog
+++ b/nptl/ChangeLog
@@ -1,5 +1,14 @@
2003-03-10 Ulrich Drepper <drepper@redhat.com>
+ * sysdeps/unix/sysv/linux/x86_64/lowlevellock.h
+ (__lll_mutex_lock_wait): Reverse order of first two parameters.
+ (__lll_mutex_timedlock_wait): Likewise.
+ (lll_mutex_lock): Adjust asm for that.
+ (lll_mutex_timedlock): Likewise. Mark cx, cc, r10 as clobbered.
+ (lll_lock): Adjust asm for operand order change.
+ * sysdeps/unix/sysv/linux/x86_64/lowlevelmutex.S: New file.
+ * sysdeps/unix/sysv/linux/x86_64/libc-lowlevelmutex.S: New file.
+
* sysdeps/unix/sysv/linux/x86_64/lowlevellock.h (__lll_lock_wait):
Reverse order of parameters.
(__lll_timedwait_tid): Remove regparms attribute.
diff --git a/nptl/sysdeps/unix/sysv/linux/x86_64/libc-lowlevelmutex.S b/nptl/sysdeps/unix/sysv/linux/x86_64/libc-lowlevelmutex.S
new file mode 100644
index 0000000000..a4ce9c2fee
--- /dev/null
+++ b/nptl/sysdeps/unix/sysv/linux/x86_64/libc-lowlevelmutex.S
@@ -0,0 +1,30 @@
+/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+ Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, write to the Free
+ Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+ 02111-1307 USA. */
+
+/* In libc.so we do not unconditionally use the lock prefix. Only if
+ the application is using threads. */
+#ifndef UP
+# define LOCK \
+ cmpl $0, __libc_multiple_threads_ptr(%rip); \
+ je 0f; \
+ lock; \
+0:
+#endif
+
+#include "lowlevelmutex.S"
diff --git a/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.S b/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.S
index ea9667d956..e7e1707a48 100644
--- a/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.S
+++ b/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.S
@@ -127,7 +127,7 @@ __lll_timedwait_tid:
/* Compute relative timeout. */
movq 8(%esp), %rax
movq $1000, %rdi
- mul %rdx /* Milli seconds to nano seconds. */
+ mul %rdi /* Milli seconds to nano seconds. */
movq (%r9), %rdi
movq 8(%r9), %rsi
subq (%rsp), %rdi
diff --git a/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.h b/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.h
index fa472baeea..f7e9450a1a 100644
--- a/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.h
+++ b/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevellock.h
@@ -42,10 +42,10 @@
/* Does not preserve %eax and %ecx. */
-extern int __lll_mutex_lock_wait (int val, int *__futex) attribute_hidden;
+extern int __lll_mutex_lock_wait (int *__futex, int __val) attribute_hidden;
/* Does not preserver %eax, %ecx, and %edx. */
-extern int __lll_mutex_timedlock_wait (int val, int *__futex,
- const struct timespec *abstime)
+extern int __lll_mutex_timedlock_wait (int *__futex, int __val,
+ const struct timespec *__abstime)
attribute_hidden;
/* Preserves all registers but %eax. */
extern int __lll_mutex_unlock_wait (int *__futex) attribute_hidden;
@@ -71,7 +71,7 @@ extern int __lll_mutex_unlock_wait (int *__futex) attribute_hidden;
"jmp 2f\n\t" \
".previous\n" \
"2:" \
- : "=D" (ignore1), "=&S" (ignore2), "=m" (futex) \
+ : "=S" (ignore1), "=&D" (ignore2), "=m" (futex) \
: "0" (1), "2" (futex) \
: "memory"); })
@@ -82,8 +82,8 @@ extern int __lll_mutex_unlock_wait (int *__futex) attribute_hidden;
"testl %0, %0\n\t" \
"jne 1f\n\t" \
".subsection 1\n" \
- "1:\tmovl %0, %%edi\n\t" \
- "leaq %4, %%rsi\n\t" \
+ "1:\tmovl %0, %%esi\n\t" \
+ "leaq %4, %%rdi\n\t" \
"movq %7, %%rdx\n\t" \
"call __lll_mutex_timedlock_wait\n\t" \
"jmp 2f\n\t" \
@@ -92,7 +92,7 @@ extern int __lll_mutex_unlock_wait (int *__futex) attribute_hidden;
: "=a" (result), "=&D" (ignore1), "=&S" (ignore2), \
"=&d" (ignore2), "=m" (futex) \
: "0" (1), "4" (futex), "m" (timeout) \
- : "memory"); \
+ : "memory", "cx", "cc", "r10"); \
result; })
@@ -157,7 +157,7 @@ extern int lll_unlock_wake_cb (int *__futex) attribute_hidden;
"jmp 2f\n\t" \
".previous\n" \
"2:" \
- : "=D" (ignore1), "=&S" (ignore2), "=m" (futex) \
+ : "=S" (ignore1), "=&D" (ignore2), "=m" (futex) \
: "0" (-1), "2" (futex) \
: "memory"); })
diff --git a/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevelmutex.S b/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevelmutex.S
new file mode 100644
index 0000000000..a494e0efaa
--- /dev/null
+++ b/nptl/sysdeps/unix/sysv/linux/x86_64/lowlevelmutex.S
@@ -0,0 +1,164 @@
+/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
+ This file is part of the GNU C Library.
+ Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
+
+ The GNU C Library is free software; you can redistribute it and/or
+ modify it under the terms of the GNU Lesser General Public
+ License as published by the Free Software Foundation; either
+ version 2.1 of the License, or (at your option) any later version.
+
+ The GNU C Library is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+ Lesser General Public License for more details.
+
+ You should have received a copy of the GNU Lesser General Public
+ License along with the GNU C Library; if not, write to the Free
+ Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+ 02111-1307 USA. */
+
+#include <sysdep.h>
+
+ .text
+
+#ifndef LOCK
+# ifdef UP
+# define LOCK
+# else
+# define LOCK lock
+# endif
+#endif
+
+#define SYS_gettimeofday __NR_gettimeofday
+#define SYS_futex 202
+#define FUTEX_WAIT 0
+#define FUTEX_WAKE 1
+
+#define EWOULDBLOCK 11
+#define EINVAL 22
+#define ETIMEDOUT 110
+
+
+ .globl __lll_mutex_lock_wait
+ .type __lll_mutex_lock_wait,@function
+ .hidden __lll_mutex_lock_wait
+ .align 16
+__lll_mutex_lock_wait:
+ pushq %r10
+ pushq %rdx
+
+ xorq %r10, %r10 /* No timeout. */
+
+1:
+ leal 1(%esi), %edx /* account for the preceeded xadd. */
+ movq %r10, %rsi /* movl $FUTEX_WAIT, %ecx */
+ movq $SYS_futex, %rax
+ syscall
+
+ movl $1, %esi
+ LOCK
+ xaddl %esi, (%rdi)
+ testl %esi, %esi
+ jne 1b
+
+ movl $2, (%rdi)
+
+ popq %rdx
+ popq %r10
+ retq
+ .size __lll_mutex_lock_wait,.-__lll_mutex_lock_wait
+
+
+#ifdef NOT_IN_libc
+ .globl __lll_mutex_timedlock_wait
+ .type __lll_mutex_timedlock_wait,@function
+ .hidden __lll_mutex_timedlock_wait
+ .align 16
+__lll_mutex_timedlock_wait:
+ /* Check for a valid timeout value. */
+ cmpq $1000000000, 4(%rdx)
+ jae 3f
+
+ /* Stack frame for the timespec and timeval structs. */
+ subq $16, %rsp
+
+ movq %rdi, %r8
+ movq %rdx, %r9
+ leal 1(%eax), %edx
+
+ /* Get current time. */
+1:
+ movq %rsp, %rdi
+ xorq %rsi, %rsi
+ movq $SYS_gettimeofday, %rax
+ syscall
+
+ /* Compute relative timeout. */
+ movq 8(%esp), %rax
+ movq $1000, %rdi
+ mul %rdi /* Milli seconds to nano seconds. */
+ movq (%r9), %rdi
+ movq 8(%r9), %rsi
+ subq (%rsp), %rdi
+ subq %rax, %rsi
+ jns 4f
+ addq $1000000000, %rsi
+ decq %rdi
+4: testq %rdi, %rdi
+ js 5f /* Time is already up. */
+
+ /* Futex call. */
+ movq %rdi, (%rsp) /* Store relative timeout. */
+ movq %rsi, 4(%rsp)
+
+ movq %rsp, %r10
+ xorq %rsi, %rsi /* movq $FUTEX_WAIT, %rsi */
+ movq %r8, %rdi
+ movq $SYS_futex, %rax
+ syscall
+
+ movl $1, %edx
+ LOCK
+ xaddl %edx, (%rdi)
+ testl %edx, %edx
+ jne 7f
+
+ movl $2, (%rdi)
+ xorl %eax, %eax
+
+ addq $16, %rsp
+ retq
+
+ /* Check whether the time expired. */
+7: cmpq $-ETIMEDOUT, %rax
+ je 5f
+ jmp 1b
+
+3: movl $EINVAL, %eax
+ retq
+
+5: movl $ETIMEDOUT, %eax
+ addq $16, %rsp
+ retq
+ .size __lll_mutex_timedlock_wait,.-__lll_mutex_timedlock_wait
+#endif
+
+
+ .globl __lll_mutex_unlock_wake
+ .type __lll_mutex_unlock_wake,@function
+ .hidden __lll_mutex_unlock_wake
+ .align 16
+__lll_mutex_unlock_wake:
+ pushq %rsi
+ pushq %rdx
+
+ movl $0, (%rdi)
+ movq $FUTEX_WAKE, %rsi
+ movl $1, %edx /* Wake one thread. */
+ movq $SYS_futex, %rax
+ syscall
+
+ popq %rdx
+ popq %rsi
+ retq
+ .size __lll_mutex_unlock_wake,.-__lll_mutex_unlock_wake
generated by cgit v1.2.3 (git 2.39.1) at 2024-05-18 14:02:37 +0000