Update.

	* sysdeps/unix/sysv/linux/x86_64/pthread_rwlock_rdlock.S: New file.
	* sysdeps/unix/sysv/linux/x86_64/pthread_rwlock_wrlock.S: New file.
	* sysdeps/unix/sysv/linux/x86_64/pthread_rwlock_unlock.S: New file.

1 files changed, 175 insertions, 0 deletions

diff --git a/nptl/sysdeps/unix/sysv/linux/x86_64/pthread_rwlock_rdlock.S b/nptl/sysdeps/unix/sysv/linux/x86_64/pthread_rwlock_rdlock.S
new file mode 100644
index 0000000000..6ef605cde1
--- /dev/null
+++ b/nptl/sysdeps/unix/sysv/linux/x86_64/pthread_rwlock_rdlock.S
@@ -0,0 +1,175 @@
+/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+   Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <lowlevelrwlock.h>
+
+
+#define SYS_futex		202
+#define FUTEX_WAIT		0
+#define FUTEX_WAKE		1
+
+#define EAGAIN		11
+#define EDEADLK		35
+
+#ifndef UP
+# define LOCK lock
+#else
+# define LOCK
+#endif
+
+
+	.text
+
+	.globl	__pthread_rwlock_rdlock
+	.type	__pthread_rwlock_rdlock,@function
+	.align	16
+__pthread_rwlock_rdlock:
+	xorq	%r10, %r10
+
+	/* Get the lock.  */
+	movl	$1, %esi
+	LOCK
+#if MUTEX == 0
+	xaddl	%esi, (%rdi)
+#else
+	xaddl	%esi, MUTEX(%rdi)
+#endif
+	testl	%esi, %esi
+	jne	1f
+
+2:	movq	WRITER(%rdi), %rax
+	testq	%rax, %rax
+	jne	14f
+	cmpl	$0, WRITERS_QUEUED(%rdi)
+	je	5f
+	cmpl	$0, FLAGS(%rdi)
+	je	5f
+
+3:	incl	READERS_QUEUED(%rdi)
+	je	4f
+
+	movl	READERS_WAKEUP(%rdi), %edx
+
+	LOCK
+#if MUTEX == 0
+	incl	(%rdi)
+#else
+	incl	MUTEX(%rdi)
+#endif
+	jne	10f
+
+11:	addq	$READERS_WAKEUP-MUTEX, %rdi
+	movq	%r10, %rsi	/* movl $FUTEX_WAIT, %ecx */
+	movq	$SYS_futex, %rax
+	syscall
+
+	subq	$READERS_WAKEUP-MUTEX, %rdi
+
+	/* Reget the lock.  */
+	movl	$1, %esi
+	LOCK
+#if MUTEX == 0
+	xaddl	%esi, (%rdi)
+#else
+	xaddl	%esi, MUTEX(%rdi)
+#endif
+	testl	%esi, %esi
+	jne	12f
+
+13:	decl	READERS_QUEUED(%rdi)
+	jmp	2b
+
+5:	xorq	%rcx, %rcx
+	incl	NR_READERS(%rdi)
+	je	8f
+9:	LOCK
+#if MUTEX == 0
+	decl	(%rdi)
+#else
+	decl	MUTEX(%rdi)
+#endif
+	jne	6f
+7:
+
+	movq	%rcx, %rax
+	retq
+
+1:
+#if MUTEX != 0
+	addq	$MUTEX, %rdi
+#endif
+	call	__lll_mutex_lock_wait
+#if MUTEX != 0
+	subq	$MUTEX, %rdi
+#endif
+	jmp	2b
+
+14:	cmpq	%gs:16, %rax
+	jne	3b
+	/* Deadlock detected.  */
+	movq	$EDEADLK, %rcx
+	jmp	9b
+
+6:
+#if MUTEX != 0
+	addq	$MUTEX, %rdi
+#endif
+	call	__lll_mutex_unlock_wake
+#if MUTEX != 0
+	subq	$MUTEX, %rdi
+#endif
+	jmp	7b
+
+	/* Overflow.  */
+8:	decl	NR_READERS(%rdi)
+	movq	$EAGAIN, %rcx
+	jmp	9b
+
+	/* Overflow.  */
+4:	decl	READERS_QUEUED(%rdi)
+	movq	$EAGAIN, %rcx
+	jmp	9b
+
+10:
+#if MUTEX != 0
+	addq	$MUTEX, %rdi
+#endif
+	call	__lll_mutex_unlock_wake
+#if MUTEX != 0
+	subq	$MUTEX, %rdi
+#endif
+	jmp	11b
+
+12:
+#if MUTEX == 0
+	addq	$MUTEX, %rdi
+#endif
+	call	__lll_mutex_lock_wait
+#if MUTEX != 0
+	subq	$MUTEX, %rdi
+#endif
+	jmp	13b
+	.size	__pthread_rwlock_rdlock,.-__pthread_rwlock_rdlock
+
+	.globl	pthread_rwlock_rdlock
+pthread_rwlock_rdlock = __pthread_rwlock_rdlock
+
+	.globl	__pthread_rwlock_rdlock_internal
+__pthread_rwlock_rdlock_internal = __pthread_rwlock_rdlock