Update.

2003-02-08  kaz Kojima  <kkojima@rr.iij4u.or.jp>

	* sysdeps/sh/Makefile: New file.
	* sysdeps/sh/bits/atomic.h: New file.
	* sysdeps/sh/pthread_spin_init.c: New file.
	* sysdeps/sh/pthread_spin_lock.c: New file.
	* sysdeps/sh/pthread_spin_trylock.S: New file.
	* sysdeps/sh/pthread_spin_unlock.S: New file.
	* sysdeps/sh/pthreaddef.h: New file.
	* sysdeps/sh/tcb-offsets.sym: New file.
	* sysdeps/sh/td_ta_map_lwp2thr.c: New file.
	* sysdeps/sh/tls.h: New file.
	* sysdeps/unix/sysv/linux/sh/bits/pthreadtypes.h: New file.
	* sysdeps/unix/sysv/linux/sh/bits/semaphore.h: New file.
	* sysdeps/unix/sysv/linux/sh/createthread.c: New file.
	* sysdeps/unix/sysv/linux/sh/fork.c: New file.
	* sysdeps/unix/sysv/linux/sh/libc-lowlevellock.S: New file.
	* sysdeps/unix/sysv/linux/sh/libc-lowlevelmutex.S: New file.
	* sysdeps/unix/sysv/linux/sh/lowlevel-atomic.h: New file.
	* sysdeps/unix/sysv/linux/sh/lowlevelcond.h: New file.
	* sysdeps/unix/sysv/linux/sh/lowlevellock.S: New file.
	* sysdeps/unix/sysv/linux/sh/lowlevellock.h: New file.
	* sysdeps/unix/sysv/linux/sh/lowlevelmutex.S: New file.
	* sysdeps/unix/sysv/linux/sh/lowlevelrwlock.h: New file.
	* sysdeps/unix/sysv/linux/sh/pt-initfini.c: New file.
	* sysdeps/unix/sysv/linux/sh/pt-vfork.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_barrier_wait.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_cond_broadcast.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_cond_signal.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_cond_timedwait.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_cond_wait.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_once.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_rwlock_rdlock.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_rwlock_timedrdlock.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_rwlock_timedwrlock.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_rwlock_unlock.S: New file.
	* sysdeps/unix/sysv/linux/sh/pthread_rwlock_wrlock.S: New file.
	* sysdeps/unix/sysv/linux/sh/sem_post.S: New file.
	* sysdeps/unix/sysv/linux/sh/sem_timedwait.S: New file.
	* sysdeps/unix/sysv/linux/sh/sem_trywait.S: New file.
	* sysdeps/unix/sysv/linux/sh/sem_wait.S: New file.
	* sysdeps/unix/sysv/linux/sh/sysdep-cancel.h: New file.

1 files changed, 202 insertions, 0 deletions

diff --git a/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_wrlock.S b/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_wrlock.S
new file mode 100644
index 0000000000..20c84235ce
--- /dev/null
+++ b/nptl/sysdeps/unix/sysv/linux/sh/pthread_rwlock_wrlock.S
@@ -0,0 +1,202 @@
+/* Copyright (C) 2003 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep.h>
+#include <lowlevelrwlock.h>
+#include <tcb-offsets.h>
+#include "lowlevel-atomic.h"
+
+#define SYS_futex		240
+#define FUTEX_WAIT		0
+#define FUTEX_WAKE		1
+
+#define EAGAIN		11
+#define EDEADLK		35
+
+
+	.text
+
+	.globl	__pthread_rwlock_wrlock
+	.type	__pthread_rwlock_wrlock,@function
+	.align	5
+__pthread_rwlock_wrlock:
+	mov.l	r12, @-r15
+	mov.l	r8, @-r15
+	sts.l	pr, @-r15
+	mov	r4, r8
+
+	/* Get the lock.  */
+	mov	#1, r3
+#if MUTEX == 0
+	XADD	(r3, @r4, r2)
+#else
+	XADD	(r3, @(MUTEX,r4), r2)
+#endif
+	tst	r2, r2
+	bf	1f
+2:
+	mov.l	@(WRITER,r8), r0
+	tst	r0, r0
+	bf	14f
+	mov.l	@(NR_READERS,r8), r0
+	tst	r0, r0
+	bt	5f
+3:
+	mov.l	@(WRITERS_QUEUED,r8), r0
+	add	#1, r0
+	mov.l	r0, @(WRITERS_QUEUED,r8)
+	tst	r0, r0
+	bt	4f
+
+#if MUTEX == 0
+	DEC (@r8, r2)
+#else
+	DEC (@(MUTEX,r8), r2)
+#endif
+	tst	r2, r2
+	bf	10f
+11:
+	mov	r8, r4
+	add	#WRITERS_WAKEUP, r4
+	mov	#FUTEX_WAIT, r5
+	mov	#0, r6
+	mov	#SYS_futex, r3
+	extu.b	r3, r3
+	trapa	#0x14
+	SYSCALL_INST_PAD
+
+	/* Reget the lock.  */
+	mov	#1, r3
+#if MUTEX == 0
+	XADD	(r3, @r4, r2)
+#else
+	XADD	(r3, @(MUTEX,r4), r2)
+#endif
+	tst	r2, r2
+	bf	12f
+13:
+	mov.l	@(READERS_QUEUED,r8), r0
+	add	#-1, r0
+	mov.l	r0, @(READERS_QUEUED,r8)
+	mov	#0, r0
+	bra	2b
+	 mov.l	r0, @(WRITERS_WAKEUP,r8)
+
+5:
+	mov	#0, r3
+	stc	gbr, r1
+	mov.w	.Ltcboff,r2
+	sub	r2,r1
+	mov.l	@(8,r1),r0
+	mov.l	r0, @(WRITER,r8)
+9:
+#if MUTEX == 0
+	DEC (@r8, r2)
+#else
+	DEC (@(MUTEX,r8), r2)
+#endif
+	tst	r2, r2
+	bf	6f
+7:
+	lds.l	@r15+, pr
+	mov.l	@r15+, r8
+	mov.l	@r15+, r12
+	rts
+	 mov	r3, r0
+
+1:
+	mov	r8, r5
+#if MUTEX != 0
+	add	#MUTEX, r5
+#endif
+	mov	r2, r4
+	mov.l	.Lwait4, r1
+	bsrf	r1
+	 nop
+.Lwait4b:
+	bra	2b
+	 nop
+14:
+	stc	gbr, r1
+	mov.w	.Ltcboff,r2
+	sub	r2,r1
+	mov.l	@(8,r1),r1
+	cmp/eq	r1, r0
+	bf	3b
+	bra	9b
+	 mov	#EDEADLK, r3
+6:
+	mov	r8, r4
+#if MUTEX != 0
+	add	#MUTEX, r4
+#endif
+	mov.l	.Lwake4, r1
+	bsrf	r1
+	 nop
+.Lwake4b:
+	bra	7b
+	 mov	#0, r3
+
+4:
+	mov.l	@(WRITERS_QUEUED,r8), r1
+	add	#-1, r1
+	mov.l	r1, @(WRITERS_QUEUED,r8)
+	bra	9b
+	 mov	#EAGAIN, r3
+
+10:
+	mov	r8, r4
+#if MUTEX != 0
+	add	#MUTEX, r4
+#endif
+	mov.l	.Lwake5, r1
+	bsrf	r1
+	 nop
+.Lwake5b:
+	bra	11b
+	 nop
+
+12:
+	mov	r8, r5
+#if MUTEX != 0
+	add	#MUTEX, r5
+#endif
+	mov	r2, r4
+	mov.l	.Lwait5, r1
+	bsrf	r1
+	 nop
+.Lwait5b:
+	bra	13b
+	 nop
+
+.Ltcboff:
+	.word	TLS_PRE_TCB_SIZE
+	.align	2
+.Lwait4:	
+	.long	__lll_mutex_lock_wait-.Lwait4b
+.Lwake4:
+	.long	__lll_mutex_unlock_wake-.Lwake4b
+.Lwait5:	
+	.long	__lll_mutex_lock_wait-.Lwait5b
+.Lwake5:
+	.long	__lll_mutex_unlock_wake-.Lwake5b
+	.globl	pthread_rwlock_wrlock
+pthread_rwlock_wrlock = __pthread_rwlock_wrlock
+
+	.globl	__pthread_rwlock_wrlock_internal
+__pthread_rwlock_wrlock_internal = __pthread_rwlock_wrlock