summaryrefslogtreecommitdiff
path: root/sysdeps/libm-i387/e_expl.S
blob: 2884efa6ce116e2b8abbd007276f97bced79e702 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
/*
 * Written by J.T. Conklin <jtc@netbsd.org>.
 * Public domain.
 *
 * Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
 */

#include <machine/asm.h>

RCSID("$NetBSD: $")

/* e^x = 2^(x * log2l(e)) */
ENTRY(__ieee754_expl)
	fldt	4(%esp)
/* I added the following ugly construct because expl(+-Inf) resulted
   in NaN.  The ugliness results from the bright minds at Intel.
   For the i686 the code can be written better.
   -- drepper@cygnus.com.  */
	fxam				/* Is NaN or +-Inf?  */
	fstsw	%ax
	sahf
	jnc	.LnoInfNaN		/* No, jump.   */
	jp	.LisInf			/* Is +-Inf, jump.  */
.LnoInfNaN:
	fldl2e
	fmulp				/* x * log2(e) */
	fstl	%st(1)
	frndint				/* int(x * log2(e)) */
	fstl	%st(2)
	fsubrp				/* fract(x * log2(e)) */
	f2xm1				/* 2^(fract(x * log2(e))) - 1 */
	fld1
	faddp				/* 2^(fract(x * log2(e))) */
	fscale				/* e^x */
	ret

.LisInf:
	andb	$2, %ah			/* Test sign.  */
	jz	.LpInf			/* If positive, jump.  */
	fldz				/* Set result to 0.  */
.LpInf:	ret
PSEUDO_END (__ieee754_expl)